Emacs Lisp ¶

The GNU Emacs website is at https://www.gnu.org/software/emacs/.
For information on using Emacs, refer to the Emacs Manual.
To view this manual in other formats, click here.

This is the GNU Emacs Lisp Reference Manual corresponding to Emacs version 31.1.50.

Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.3 or any later version published by the Free Software Foundation; with the Invariant Sections being “GNU General Public License,” with the Front-Cover Texts being “A GNU Manual,” and with the Back-Cover Texts as in (a) below. A copy of the license is included in the section entitled “GNU Free Documentation License.”

(a) The FSF’s Back-Cover Text is: “You have the freedom to copy and modify this GNU manual. Buying copies from the FSF supports it in developing GNU and promoting software freedom.”

Short Table of Contents

Next: Lisp Data Types, Previous: Emacs Lisp, Up: Emacs Lisp [Contents][Index]

1 Introduction ¶

Most of the GNU Emacs text editor is written in the programming language called Emacs Lisp. You can write new code in Emacs Lisp and install it as an extension to the editor. However, Emacs Lisp is more than a mere extension language; it is a full computer programming language in its own right. You can use it as you would any other programming language.

Because Emacs Lisp is designed for use in an editor, it has special features for scanning and parsing text as well as features for handling files, buffers, displays, subprocesses, and so on. Emacs Lisp is closely integrated with the editing facilities; thus, editing commands are functions that can also conveniently be called from Lisp programs, and parameters for customization are ordinary Lisp variables.

This manual attempts to be a full description of Emacs Lisp. For a beginner’s introduction to Emacs Lisp, see An Introduction to Emacs Lisp Programming, by Bob Chassell, also published by the Free Software Foundation. This manual presumes considerable familiarity with the use of Emacs for editing; see The GNU Emacs Manual for this basic information.

Generally speaking, the earlier chapters describe features of Emacs Lisp that have counterparts in many programming languages, and later chapters describe features that are peculiar to Emacs Lisp or relate specifically to editing.

This is the GNU Emacs Lisp Reference Manual, corresponding to Emacs version 31.1.50.

Next: Lisp History, Up: Introduction [Contents][Index]

1.1 Caveats ¶

This manual has gone through numerous drafts. It is nearly complete but not flawless. There are a few topics that are not covered, either because we consider them secondary (such as most of the individual modes) or because they are yet to be written. Because we are not able to deal with them completely, we have left out several parts intentionally.

The manual should be fully correct in what it does cover, and it is therefore open to criticism on anything it says—from specific examples and descriptive text, to the ordering of chapters and sections. If something is confusing, or you find that you have to look at the sources or experiment to learn something not covered in the manual, then perhaps the manual should be fixed. Please let us know.

As you use this manual, we ask that you send corrections as soon as you find them. If you think of a simple, real life example for a function or group of functions, please make an effort to write it up and send it in. Please reference any comments to the node name and function or variable name, as appropriate. Also state the number of the edition you are criticizing.

Please send comments and corrections using M-x report-emacs-bug. For more details, See Reporting Bugs in The GNU Emacs Manual.

Next: Conventions, Previous: Caveats, Up: Introduction [Contents][Index]

1.2 Lisp History ¶

Lisp (LISt Processing language) was first developed in the late 1950s at the Massachusetts Institute of Technology for research in artificial intelligence. The great power of the Lisp language makes it ideal for other purposes as well, such as writing editing commands.

Dozens of Lisp implementations have been built over the years, each with its own idiosyncrasies. Many of them were inspired by Maclisp, which was written in the 1960s at MIT’s Project MAC. Eventually the implementers of the descendants of Maclisp came together and developed a standard for Lisp systems, called Common Lisp. In the meantime, Gerry Sussman and Guy Steele at MIT developed a simplified but very powerful dialect of Lisp, called Scheme.

GNU Emacs Lisp is largely inspired by Maclisp, and a little by Common Lisp. If you know Common Lisp, you will notice many similarities. However, many features of Common Lisp have been omitted or simplified in order to reduce the memory requirements of GNU Emacs. Sometimes the simplifications are so drastic that a Common Lisp user might be very confused. We will occasionally point out how GNU Emacs Lisp differs from Common Lisp. If you don’t know Common Lisp, don’t worry about it; this manual is self-contained.

A certain amount of Common Lisp emulation is available via the cl-lib library. See Overview in Common Lisp Extensions.

Emacs Lisp is not at all influenced by Scheme; but the GNU project has an implementation of Scheme, called Guile. We use it in all new GNU software that calls for extensibility.

Next: Version Information, Previous: Lisp History, Up: Introduction [Contents][Index]

1.3 Conventions ¶

This section explains the notational conventions that are used in this manual. You may want to skip this section and refer back to it later.

Next: nil and t, Up: Conventions [Contents][Index]

1.3.1 Some Terms ¶

Throughout this manual, the phrases “the Lisp reader” and “the Lisp printer” refer to those routines in Lisp that convert textual representations of Lisp objects into actual Lisp objects, and vice versa. See Printed Representation and Read Syntax, for more details. You, the person reading this manual, are thought of as the programmer and are addressed as “you”. The user is the person who uses Lisp programs, including those you write.

Examples of Lisp code are formatted like this: (list 1 2 3). Names that represent metasyntactic variables, or arguments to a function being described, are formatted like this: first-number.

Next: Evaluation Notation, Previous: Some Terms, Up: Conventions [Contents][Index]

1.3.2 `nil` and `t` ¶

In Emacs Lisp, the symbol nil has three separate meanings: it is a symbol with the name ‘nil’; it is the logical truth value false; and it is the empty list—the list of zero elements. When used as a variable, nil always has the value nil.

As far as the Lisp reader is concerned, ‘()’ and ‘nil’ are identical: they stand for the same object, the symbol nil. The different ways of writing the symbol are intended entirely for human readers. After the Lisp reader has read either ‘()’ or ‘nil’, there is no way to determine which representation was actually written by the programmer.

In this manual, we write () when we wish to emphasize that it means the empty list, and we write nil when we wish to emphasize that it means the truth value false. That is a good convention to use in Lisp programs also.

(cons 'foo ())                ; Emphasize the empty list
(setq foo-flag nil)           ; Emphasize the truth value false

In contexts where a truth value is expected, any non-nil value is considered to be true. However, t is the preferred way to represent the truth value true. When you need to choose a value that represents true, and there is no other basis for choosing, use t. The symbol t always has the value t.

In Emacs Lisp, nil and t are special symbols that always evaluate to themselves. This is so that you do not need to quote them to use them as constants in a program. An attempt to change their values results in a setting-constant error. See Variables that Never Change.

Function: booleanp object ¶: Return non-nil if object is one of the two canonical boolean values: t or nil.

Next: Printing Notation, Previous: nil and t, Up: Conventions [Contents][Index]

1.3.3 Evaluation Notation ¶

A Lisp expression that you can evaluate is called a form. Evaluating a form always produces a result, which is a Lisp object. In the examples in this manual, this is indicated with ‘⇒’:

(car '(1 2))
     ⇒ 1

You can read this as “(car '(1 2)) evaluates to 1”.

When a form is a macro call, it expands into a new form for Lisp to evaluate. We show the result of the expansion with ‘→’. We may or may not show the result of the evaluation of the expanded form.

(third '(a b c))
     → (car (cdr (cdr '(a b c))))
     ⇒ c

To help describe one form, we sometimes show another form that produces identical results. The exact equivalence of two forms is indicated with ‘≡’.

(make-sparse-keymap) ≡ (list 'keymap)

Next: Error Messages, Previous: Evaluation Notation, Up: Conventions [Contents][Index]

1.3.4 Printing Notation ¶

Many of the examples in this manual print text when they are evaluated. If you execute example code in a Lisp Interaction buffer (such as the buffer *scratch*) by typing C-j after the closing parenthesis of the example, the printed text is inserted into the buffer. If you execute the example by other means (such as by evaluating the function eval-region), the printed text is displayed in the echo area.

Examples in this manual indicate printed text with ‘-|’, irrespective of where that text goes. The value returned by evaluating the form follows on a separate line with ‘⇒’.

(progn (prin1 'foo) (princ "\n") (prin1 'bar))
     -| foo
     -| bar
     ⇒ bar

Next: Buffer Text Notation, Previous: Printing Notation, Up: Conventions [Contents][Index]

1.3.5 Error Messages ¶

Some examples signal errors. This normally displays an error message in the echo area. We show the error message on a line starting with ‘error→’. Note that ‘error→’ itself does not appear in the echo area.

(+ 23 'x)
error→ Wrong type argument: number-or-marker-p, x

Next: Format of Descriptions, Previous: Error Messages, Up: Conventions [Contents][Index]

1.3.6 Buffer Text Notation ¶

Some examples describe modifications to the contents of a buffer, by showing the before and after versions of the text. These examples show the contents of the buffer in question between two lines of dashes containing the buffer name. In addition, ‘∗’ indicates the location of point. (The symbol for point, of course, is not part of the text in the buffer; it indicates the place between two characters where point is currently located.)

---------- Buffer: foo ----------
This is the ∗contents of foo.
---------- Buffer: foo ----------
(insert "changed ")
     ⇒ nil
---------- Buffer: foo ----------
This is the changed ∗contents of foo.
---------- Buffer: foo ----------

Previous: Buffer Text Notation, Up: Conventions [Contents][Index]

1.3.7 Format of Descriptions ¶

Functions, variables, macros, commands, user options, and special forms are described in this manual in a uniform format. The first line of a description contains the name of the item followed by its arguments, if any. The category—function, variable, or whatever—appears at the beginning of the line. The description follows on succeeding lines, sometimes with examples.

Next: A Sample Variable Description, Up: Format of Descriptions [Contents][Index]

1.3.7.1 A Sample Function Description ¶

In a function description, the name of the function being described appears first. It is followed on the same line by a list of argument names. These names are also used in the body of the description, to stand for the values of the arguments.

The appearance of the keyword &optional in the argument list indicates that the subsequent arguments may be omitted (omitted arguments default to nil). Do not write &optional when you call the function.

The keyword &rest (which must be followed by a single argument name) indicates that any number of arguments can follow. The single argument name following &rest receives, as its value, a list of all the remaining arguments passed to the function. Do not write &rest when you call the function.

Here is a description of an imaginary function foo:

Function: foo integer1 &optional integer2 &rest integers ¶

The function foo subtracts integer1 from integer2, then adds all the rest of the arguments to the result. If integer2 is not supplied, then the number 19 is used by default.

(foo 1 5 3 9)
     ⇒ 16
(foo 5)
     ⇒ 14

More generally,

(foo w x y...)
≡
(+ (- x w) y...)

By convention, any argument whose name contains the name of a type (e.g., integer, integer1 or buffer) is expected to be of that type. A plural of a type (such as buffers) often means a list of objects of that type. An argument named object may be of any type. (For a list of Emacs object types, see Lisp Data Types.) An argument with any other sort of name (e.g., new-file) is specific to the function; if the function has a documentation string, the type of the argument should be described there (see Documentation).

See Lambda Expressions, for a more complete description of arguments modified by &optional and &rest.

Command, macro, and special form descriptions have the same format, but the word ‘Function’ is replaced by ‘Command’, ‘Macro’, or ‘Special Form’, respectively. Commands are simply functions that may be called interactively; macros process their arguments differently from functions (the arguments are not evaluated), but are presented the same way.

The descriptions of macros and special forms use a more complex notation to specify optional and repeated arguments, because they can break the argument list down into separate arguments in more complicated ways. ‘[optional-arg]’ means that optional-arg is optional and ‘repeated-args…’ stands for zero or more arguments. Parentheses are used when several arguments are grouped into additional levels of list structure. Here is an example:

Special Form: count-loop (var [from to [inc]]) body… ¶

This imaginary special form implements a loop that executes the body forms and then increments the variable var on each iteration. On the first iteration, the variable has the value from; on subsequent iterations, it is incremented by one (or by inc if that is given). The loop exits before executing body if var equals to. Here is an example:

(count-loop (i 0 10)
  (prin1 i) (princ " ")
  (prin1 (aref vector i))
  (terpri))

If from and to are omitted, var is bound to nil before the loop begins, and the loop exits if var is non-nil at the beginning of an iteration. Here is an example:

(count-loop (done)
  (if (pending)
      (fixit)
    (setq done t)))

In this special form, the arguments from and to are optional, but must both be present or both absent. If they are present, inc may optionally be specified as well. These arguments are grouped with the argument var into a list, to distinguish them from body, which includes all remaining elements of the form.

Previous: A Sample Function Description, Up: Format of Descriptions [Contents][Index]

1.3.7.2 A Sample Variable Description ¶

A variable is a name that can be bound (or set) to an object. The object to which a variable is bound is called a value; we say also that variable holds that value. Although nearly all variables can be set by the user, certain variables exist specifically so that users can change them; these are called user options. Ordinary variables and user options are described using a format like that for functions, except that there are no arguments.

Here is a description of the imaginary electric-future-map variable.

Variable: electric-future-map ¶: The value of this variable is a full keymap used by Electric Command Future mode. The functions in this map allow you to edit commands you have not yet thought about executing.

User option descriptions have the same format, but ‘Variable’ is replaced by ‘User Option’.

Next: Acknowledgments, Previous: Conventions, Up: Introduction [Contents][Index]

1.4 Version Information ¶

These facilities provide information about which version of Emacs is in use.

Command: emacs-version &optional here ¶

This function returns a string describing the version of Emacs that is running. It is useful to include this string in bug reports.

(emacs-version)
  ⇒ "GNU Emacs 26.1 (build 1, x86_64-unknown-linux-gnu,
             GTK+ Version 3.16) of 2017-06-01"

If here is non-nil, it inserts the text in the buffer before point, and returns nil. When this function is called interactively, it prints the same information in the echo area, but giving a prefix argument makes here non-nil.

Variable: emacs-build-time ¶

The value of this variable indicates the time at which Emacs was built. It uses the style of current-time (see Time of Day), or is nil if the information is not available.

emacs-build-time
     ⇒ (25194 55894 8547 617000)

(This timestamp is (1651169878008547617 . 1000000000) if current-time-list was nil when Emacs was built.)

Variable: emacs-version ¶: The value of this variable is the version of Emacs being run. It is a string such as "26.1". A value with three numeric components, such as "26.0.91", indicates an unreleased test version. (Prior to Emacs 26.1, the string includes an extra final component with the integer that is now stored in emacs-build-number; e.g., "25.1.1".)

Variable: emacs-major-version ¶: The major version number of Emacs, as an integer. For Emacs version 23.1, the value is 23.

Variable: emacs-minor-version ¶: The minor version number of Emacs, as an integer. For Emacs version 23.1, the value is 1.

Variable: emacs-build-number ¶: An integer that increments each time Emacs is built in the same directory (without cleaning). This is only of relevance when developing Emacs.

Variable: emacs-repository-version ¶: A string that gives the repository revision from which Emacs was built. If Emacs was built outside revision control, the value is nil.

Variable: emacs-repository-branch ¶: A string that gives the repository branch from which Emacs was built. In the most cases this is "master". If Emacs was built outside revision control, the value is nil.

Previous: Version Information, Up: Introduction [Contents][Index]

1.5 Acknowledgments ¶

This manual was originally written by Robert Krawitz, Bil Lewis, Dan LaLiberte, Richard M. Stallman and Chris Welty, the volunteers of the GNU manual group, in an effort extending over several years. Robert J. Chassell helped to review and edit the manual, with the support of the Defense Advanced Research Projects Agency, ARPA Order 6082, arranged by Warren A. Hunt, Jr. of Computational Logic, Inc. Additional sections have since been written by Miles Bader, Lars Brinkhoff, Chong Yidong, Kenichi Handa, Lute Kamstra, Juri Linkov, Glenn Morris, Thien-Thi Nguyen, Dan Nicolaescu, Martin Rudalics, Kim F. Storm, Luc Teirlinck, and Eli Zaretskii, and others.

Corrections were supplied by Drew Adams, Juanma Barranquero, Karl Berry, Jim Blandy, Bard Bloom, Stephane Boucher, David Boyes, Alan Carroll, Richard Davis, Lawrence R. Dodd, Peter Doornbosch, David A. Duff, Chris Eich, Beverly Erlebacher, David Eckelkamp, Ralf Fassel, Eirik Fuller, Stephen Gildea, Bob Glickstein, Eric Hanchrow, Jesper Harder, George Hartzell, Nathan Hess, Masayuki Ida, Dan Jacobson, Jak Kirman, Bob Knighten, Frederick M. Korz, Joe Lammens, Glenn M. Lewis, K. Richard Magill, Brian Marick, Roland McGrath, Stefan Monnier, Skip Montanaro, John Gardiner Myers, Thomas A. Peterson, Francesco Potortì, Friedrich Pukelsheim, Arnold D. Robbins, Raul Rockwell, Jason Rumney, Per Starbäck, Shinichirou Sugou, Kimmo Suominen, Edward Tharp, Bill Trost, Rickard Westman, Jean White, Eduard Wiebe, Matthew Wilding, Carl Witty, Dale Worley, Rusty Wright, and David D. Zuhn.

For a more complete list of contributors, please see the relevant change log entries in the Emacs source repository.

Next: Numbers, Previous: Introduction, Up: Emacs Lisp [Contents][Index]

2 Lisp Data Types ¶

A Lisp object is a piece of data used and manipulated by Lisp programs. For our purposes, a type or data type is a set of possible objects.

Every object belongs to at least one type. Objects of the same type have similar structures and may usually be used in the same contexts. Types can overlap, and objects can belong to two or more types. Consequently, we can ask whether an object belongs to a particular type, but not for the type of an object.

A few fundamental object types are built into Emacs. These, from which all other types are constructed, are called primitive types. Each object belongs to one and only one primitive type. These types include integer, float, cons, symbol, string, vector, hash-table, subr, byte-code function, and record, plus several special types, such as buffer, that are related to editing. (See Editing Types.)

Each primitive type has a corresponding Lisp function that checks whether an object is a member of that type.

Lisp is unlike many other languages in that its objects are self-typing: the primitive type of each object is implicit in the object itself. For example, if an object is a vector, nothing can treat it as a number; Lisp knows it is a vector, not a number.

In most languages, the programmer must declare the data type of each variable, and the type is known by the compiler but not represented in the data. Such type declarations do not exist in Emacs Lisp. A Lisp variable can have any type of value, and it remembers whatever value you store in it, type and all. (Actually, a small number of Emacs Lisp variables can only take on values of a certain type. See Variables with Restricted Values.)

This chapter describes the purpose, printed representation, and read syntax of each of the standard types in GNU Emacs Lisp. Details on how to use these types can be found in later chapters.

Next: Special Read Syntax, Up: Lisp Data Types [Contents][Index]

2.1 Printed Representation and Read Syntax ¶

The printed representation of an object is the format of the output generated by the Lisp printer (the function prin1) for that object. Every data type has a unique printed representation. The read syntax of an object is the format of the input accepted by the Lisp reader (the function read) for that object. This is not necessarily unique; many kinds of object have more than one syntax. See Reading and Printing Lisp Objects.

In most cases, an object’s printed representation is also a read syntax for the object. However, some types have no read syntax, since it does not make sense to enter objects of these types as constants in a Lisp program. These objects are printed in hash notation, which consists of the characters ‘#<’, a descriptive string (typically the type name followed by the name of the object), and a closing ‘>’. (This is called “hash notation” because it begins with the ‘#’ character, known as “hash” or “number sign”). For example:

(current-buffer)
     ⇒ #<buffer objects.texi>

Hash notation cannot be read at all, so the Lisp reader signals the error invalid-read-syntax whenever it encounters ‘#<’.

We describe the read syntax and the printed representation of each Lisp data type where we describe that data type, in the following sections of this chapter. For example, see String Type, and its subsections for the read syntax and printed representation of strings; see Vector Type for the same information about vectors; etc.

In other languages, an expression is text; it has no other form. In Lisp, an expression is primarily a Lisp object and only secondarily the text that is the object’s read syntax. Often there is no need to emphasize this distinction, but you must keep it in the back of your mind, or you will occasionally be very confused.

When you evaluate an expression interactively, the Lisp interpreter first reads the textual representation of it, producing a Lisp object, and then evaluates that object (see Evaluation). However, evaluation and reading are separate activities. Reading returns the Lisp object represented by the text that is read; the object may or may not be evaluated later. See Input Functions, for a description of read, the basic function for reading objects.

Next: Comments, Previous: Printed Representation and Read Syntax, Up: Lisp Data Types [Contents][Index]

2.2 Special Read Syntax ¶

Emacs Lisp represents many special objects and constructs via special hash notations.

‘#<…>’

Objects that have no read syntax are presented like this (see Printed Representation and Read Syntax).

‘##’

The printed representation of an interned symbol whose name is an empty string (see Symbol Type).

‘#'’

This is a shortcut for function, see Anonymous Functions.

‘#:’

The printed representation of an uninterned symbol whose name is foo is ‘#:foo’ (see Symbol Type).

‘#N’

When printing circular structures, this construct is used to represent where the structure loops back onto itself, and ‘N’ is the starting list count:

(let ((a (list 1)))
  (setcdr a a))
=> (1 . #0)

‘#N=’

‘#N#’

‘#N=’ gives the name to an object, and ‘#N#’ represents that object, so when reading back the object, they will be the same object instead of copies (see Read Syntax for Circular Objects).

‘#xN’

‘N’ represented as a hexadecimal number (‘#x2a’).

‘#oN’

‘N’ represented as an octal number (‘#o52’).

‘#bN’

‘N’ represented as a binary number (‘#b101010’).

‘#(…)’

String text properties (see Text Properties in Strings).

‘#^’

A char table (see Char-Table Type).

‘#s(hash-table …)’

A hash table (see Hash Table Type).

‘?C’

A character (see Basic Char Syntax).

‘#$’

The current file name in byte-compiled files (see Documentation Strings and Compilation). This is not meant to be used in Emacs Lisp source files.

‘#@N’

Skip the next ‘N’ characters (see Comments). This is used in byte-compiled files, and is not meant to be used in Emacs Lisp source files.

‘#f’

Indicates that the following form isn’t readable by the Emacs Lisp reader. This is only in text for display purposes (when that would look prettier than alternative ways of indicating an unreadable form) and will never appear in any Lisp file.

Next: Editing Types, Previous: Comments, Up: Lisp Data Types [Contents][Index]

2.4 Programming Types ¶

There are two general categories of types in Emacs Lisp: those having to do with Lisp programming, and those having to do with editing. The former exist in many Lisp implementations, in one form or another. The latter are unique to Emacs Lisp.

Next: Floating-Point Type, Up: Programming Types [Contents][Index]

2.4.1 Integer Type ¶

Under the hood, there are two kinds of integers—small integers, called fixnums, and large integers, called bignums.

The range of values for a fixnum depends on the machine. The minimum range is −536,870,912 to 536,870,911 (30 bits; i.e., −2**29 to 2**29 − 1) but many machines provide a wider range.

Bignums can have arbitrary precision. Operations that overflow a fixnum will return a bignum instead.

All numbers can be compared with eql or =; fixnums can also be compared with eq. To test whether an integer is a fixnum or a bignum, you can compare it to most-negative-fixnum and most-positive-fixnum, or you can use the convenience predicates fixnump and bignump on any object.

The read syntax for integers is a sequence of (base ten) digits with an optional sign at the beginning and an optional period at the end. The printed representation produced by the Lisp interpreter never has a leading ‘+’ or a final ‘.’.

-1               ; The integer −1.
1                ; The integer 1.
1.               ; Also the integer 1.
+1               ; Also the integer 1.

See Numbers, for more information.

Next: Character Type, Previous: Integer Type, Up: Programming Types [Contents][Index]

2.4.2 Floating-Point Type ¶

Floating-point numbers are the computer equivalent of scientific notation; you can think of a floating-point number as a fraction together with a power of ten. The precise number of significant figures and the range of possible exponents is machine-specific; Emacs uses the C data type double to store the value, and internally this records a power of 2 rather than a power of 10.

The printed representation for floating-point numbers requires either a decimal point (with at least one digit following), an exponent, or both. For example, ‘1500.0’, ‘+15e2’, ‘15.0e+2’, ‘+1500000e-3’, and ‘.15e4’ are five ways of writing a floating-point number whose value is 1500. They are all equivalent.

See Numbers, for more information.

Next: Symbol Type, Previous: Floating-Point Type, Up: Programming Types [Contents][Index]

2.4.3 Character Type ¶

A character in Emacs Lisp is nothing more than an integer. In other words, characters are represented by their character codes. For example, the character A is represented as the integer 65. That is also their usual printed representation; see Basic Char Syntax.

Individual characters are used occasionally in programs, but it is more common to work with strings, which are sequences composed of characters. See String Type.

Characters in strings and buffers are currently limited to the range of 0 to 4194303—twenty two bits (see Character Codes). Codes 0 through 127 are ASCII codes; the rest are non-ASCII (see Non-ASCII Characters). Characters that represent keyboard input have a much wider range, to encode modifier keys such as Control, Meta and Shift.

There are special functions for producing a human-readable textual description of a character for the sake of messages. See Describing Characters for Help Messages.

Next: General Escape Syntax, Up: Character Type [Contents][Index]

2.4.3.1 Basic Char Syntax ¶

Since characters are really integers, the printed representation of a character is a decimal number. This is also a possible read syntax for a character, but writing characters that way in Lisp programs is not clear programming. You should always use the special read syntax formats that Emacs Lisp provides for characters. These syntax formats start with a question mark.

The usual read syntax for alphanumeric characters is a question mark followed by the character; thus, ‘?A’ for the character A, ‘?B’ for the character B, and ‘?a’ for the character a.

For example:

?Q ⇒ 81     ?q ⇒ 113

You can use the same syntax for punctuation characters. However, if the punctuation character has a special syntactic meaning in Lisp, you must quote it with a ‘\’. For example, ‘?\(’ is the way to write the open-paren character. Likewise, if the character is ‘\’, you must use a second ‘\’ to quote it: ‘?\\’.

You can express the characters control-g, backspace, tab, newline, vertical tab, formfeed, space, return, del, and escape as ‘?\a’, ‘?\b’, ‘?\t’, ‘?\n’, ‘?\v’, ‘?\f’, ‘?\s’, ‘?\r’, ‘?\d’, and ‘?\e’, respectively. (‘?\s’ followed by a dash has a different meaning—it applies the Super modifier to the following character.) Thus,

?\a ⇒ 7                 ; control-g, C-g
?\b ⇒ 8                 ; backspace, BS, C-h
?\t ⇒ 9                 ; tab, TAB, C-i
?\n ⇒ 10                ; newline, C-j
?\v ⇒ 11                ; vertical tab, C-k
?\f ⇒ 12                ; formfeed character, C-l
?\r ⇒ 13                ; carriage return, RET, C-m
?\e ⇒ 27                ; escape character, ESC, C-[
?\s ⇒ 32                ; space character, SPC
?\\ ⇒ 92                ; backslash character, \
?\d ⇒ 127               ; delete character, DEL

These sequences which start with backslash are also known as escape sequences, because backslash plays the role of an escape character; this has nothing to do with the character ESC. ‘\s’ is meant for use in character constants; in string constants, just write the space.

A backslash is allowed, and harmless, preceding any character without a special escape meaning; thus, ‘?\+’ is equivalent to ‘?+’. There is no reason to add a backslash before most characters. However, you must add a backslash before any of the characters ‘()[]\;"’, and you should add a backslash before any of the characters ‘|'`#.,’ to avoid confusing the Emacs commands for editing Lisp code. You should also add a backslash before Unicode characters which resemble the previously mentioned ASCII ones, to avoid confusing people reading your code. Emacs will highlight some non-escaped commonly confused characters such as ‘‘’ to encourage this. You can also add a backslash before whitespace characters such as space and tab. However, it is cleaner to use one of the easily readable escape sequences, such as ‘\t’ or ‘\s’, instead of an actual whitespace character such as a tab or a space. (If you do write backslash followed by a space, you should write an extra space after the character constant to separate it from the following text.)

Next: Control-Character Syntax, Previous: Basic Char Syntax, Up: Character Type [Contents][Index]

2.4.3.2 General Escape Syntax ¶

In addition to the specific escape sequences for special important control characters, Emacs provides several types of escape syntax that you can use to specify non-ASCII text characters.

You can specify characters by their Unicode names, if any. ?\N{NAME} represents the Unicode character named NAME. Thus, ‘?\N{LATIN SMALL LETTER A WITH GRAVE}’ is equivalent to ?à and denotes the Unicode character U+00E0. To simplify entering multi-line strings, you can replace spaces in the names by non-empty sequences of whitespace (e.g., newlines).
You can specify characters by their Unicode values. ?\N{U+X} represents a character with Unicode code point X, where X is a hexadecimal number. Also, ?\uxxxx and ?\Uxxxxxxxx represent code points xxxx and xxxxxxxx, respectively, where each x is a single hexadecimal digit. For example, ?\N{U+E0}, ?\u00e0 and ?\U000000E0 are all equivalent to ?à and to ‘?\N{LATIN SMALL LETTER A WITH GRAVE}’. The Unicode Standard defines code points only up to ‘U+10ffff’, so if you specify a code point higher than that, Emacs signals an error.
You can specify characters by their hexadecimal character codes. A hexadecimal escape sequence consists of a backslash, ‘x’, and the hexadecimal character code. Thus, ‘?\x41’ is the character A, ‘?\x1’ is the character C-a, and ?\xe0 is the character à (a with grave accent). You can use one or more hex digits after ‘x’, so you can represent any character code in this way.
You can specify characters by their character code in octal. An octal escape sequence consists of a backslash followed by up to three octal digits; thus, ‘?\101’ for the character A, ‘?\001’ for the character C-a, and ?\002 for the character C-b. Only characters up to octal code 777 can be specified this way.

These escape sequences may also be used in strings. See Non-ASCII Characters in Strings.

Next: Meta-Character Syntax, Previous: General Escape Syntax, Up: Character Type [Contents][Index]

2.4.3.3 Control-Character Syntax ¶

Control characters can be represented using yet another read syntax. This consists of a question mark followed by a backslash, caret, and the corresponding non-control character, in either upper or lower case. For example, both ‘?\^I’ and ‘?\^i’ are valid read syntax for the character C-i, the character whose value is 9.

Instead of the ‘^’, you can use ‘C-’; thus, ‘?\C-i’ is equivalent to ‘?\^I’ and to ‘?\^i’:

?\^I ⇒ 9     ?\C-I ⇒ 9

In strings and buffers, the only control characters allowed are those that exist in ASCII; but for keyboard input purposes, you can turn any character into a control character with ‘C-’. The character codes for these non-ASCII control characters include the 2**26 bit as well as the code for the corresponding non-control character. Not all text terminals can generate non-ASCII control characters, but it is straightforward to generate them using X and other window systems.

For historical reasons, Emacs treats the DEL character as the control equivalent of ?:

?\^? ⇒ 127     ?\C-? ⇒ 127

As a result, it is currently not possible to represent the character Control-?, which is a meaningful input character under X, using ‘\C-’. It is not easy to change this, as various Lisp files refer to DEL in this way.

For representing control characters to be found in files or strings, we recommend the ‘^’ syntax; for control characters in keyboard input, we prefer the ‘C-’ syntax. Which one you use does not affect the meaning of the program, but may guide the understanding of people who read it.

Previous: Meta-Character Syntax, Up: Character Type [Contents][Index]

2.4.3.5 Other Character Modifier Bits ¶

The case of a graphic character is indicated by its character code; for example, ASCII distinguishes between the characters ‘a’ and ‘A’. But ASCII has no way to represent whether a control character is upper case or lower case. Emacs uses the 2**25 bit to indicate that the shift key was used in typing a control character. This distinction is possible only on a graphical display such as a GUI display on X; text terminals do not report the distinction. The Lisp syntax for the shift bit is ‘\S-’; thus, ‘?\C-\S-o’ or ‘?\C-\S-O’ represents the shifted-control-o character.

The X Window System defines three other modifier bits that can be set in a character: hyper, super and alt. The syntaxes for these bits are ‘\H-’, ‘\s-’ and ‘\A-’. (Case is significant in these prefixes.) Thus, ‘?\H-\M-\A-x’ represents Alt-Hyper-Meta-x. (Note that ‘\s’ with no following ‘-’ represents the space character.) Numerically, the bit values are 2**22 for alt, 2**23 for super and 2**24 for hyper.

Next: Sequence Types, Previous: Character Type, Up: Programming Types [Contents][Index]

2.4.4 Symbol Type ¶

A symbol in GNU Emacs Lisp is an object with a name. The symbol name serves as the printed representation of the symbol. In ordinary Lisp use, with one single obarray (see Creating and Interning Symbols), a symbol’s name is unique—no two symbols have the same name.

A symbol can serve as a variable, as a function name, or to hold a property list. Or it may serve only to be distinct from all other Lisp objects, so that its presence in a data structure may be recognized reliably. In a given context, usually only one of these uses is intended. But you can use one symbol in all of these ways, independently.

A symbol whose name starts with a colon (‘:’) is called a keyword symbol. These symbols automatically act as constants, and are normally used only by comparing an unknown symbol with a few specific alternatives. See Variables that Never Change.

A symbol name can contain any characters whatever. Most symbol names are written with letters, digits, and the punctuation characters ‘-+=*/’. Such names require no special punctuation; the characters of the name suffice as long as the name does not look like a number. (If it does, write a ‘\’ at the beginning of the name to force interpretation as a symbol.) The characters ‘_~!@$%^&:<>{}?’ are less often used but also require no special punctuation. Any other characters may be included in a symbol’s name by escaping them with a backslash. In contrast to its use in strings, however, a backslash in the name of a symbol simply quotes the single character that follows the backslash. For example, in a string, ‘\t’ represents a tab character; in the name of a symbol, however, ‘\t’ merely quotes the letter ‘t’. To have a symbol with a tab character in its name, you must actually use a tab (preceded with a backslash). But it’s rare to do such a thing.

Common Lisp note: In Common Lisp, lower case letters are always folded to upper case, unless they are explicitly escaped. In Emacs Lisp, upper case and lower case letters are distinct.

Here are several examples of symbol names. Note that the ‘+’ in the fourth example is escaped to prevent it from being read as a number. This is not necessary in the sixth example because the rest of the name makes it invalid as a number.

foo                 ; A symbol named ‘foo’.
FOO                 ; A symbol named ‘FOO’, different from ‘foo’.

1+                  ; A symbol named ‘1+’
                    ;   (not ‘+1’, which is an integer).

\+1                 ; A symbol named ‘+1’
                    ;   (not a very readable name).

\(*\ 1\ 2\)         ; A symbol named ‘(* 1 2)’ (a worse name).
+-*/_~!@$%^&=:<>{}  ; A symbol named ‘+-*/_~!@$%^&=:<>{}’.
                    ;   These characters need not be escaped.

As an exception to the rule that a symbol’s name serves as its printed representation, ‘##’ is the printed representation for an interned symbol whose name is an empty string. Furthermore, ‘#:foo’ is the printed representation for an uninterned symbol whose name is foo. (Normally, the Lisp reader interns all symbols; see Creating and Interning Symbols.)

Next: Cons Cell and List Types, Previous: Symbol Type, Up: Programming Types [Contents][Index]

2.4.5 Sequence Types ¶

A sequence is a Lisp object that represents an ordered set of elements. There are two kinds of sequence in Emacs Lisp: lists and arrays.

Lists are the most commonly-used sequences. A list can hold elements of any type, and its length can be easily changed by adding or removing elements. See the next subsection for more about lists.

Arrays are fixed-length sequences. They are further subdivided into strings, vectors, char-tables and bool-vectors. Vectors can hold elements of any type, whereas string elements must be characters, and bool-vector elements must be t or nil. Char-tables are like vectors except that they are indexed by any valid character code. The characters in a string can have text properties like characters in a buffer (see Text Properties), but vectors do not support text properties, even when their elements happen to be characters.

Lists, strings and the other array types also share important similarities. For example, all have a length l, and all have elements which can be indexed from zero to l minus one. Several functions, called sequence functions, accept any kind of sequence. For example, the function length reports the length of any kind of sequence. See Sequences, Arrays, and Vectors.

It is generally impossible to read the same sequence twice, since sequences are always created anew upon reading. If you read the read syntax for a sequence twice, you get two sequences with equal contents. There is one exception: the empty list () always stands for the same object, nil.

Next: Array Type, Previous: Sequence Types, Up: Programming Types [Contents][Index]

2.4.6 Cons Cell and List Types ¶

A cons cell is an object that consists of two slots, called the CAR slot and the CDR slot. Each slot can hold any Lisp object. We also say that the CAR of this cons cell is whatever object its CAR slot currently holds, and likewise for the CDR.

A list is a series of cons cells, linked together so that the CDR slot of each cons cell holds either the next cons cell or the empty list. The empty list is actually the symbol nil. See Lists, for details. Because most cons cells are used as part of lists, we refer to any structure made out of cons cells as a list structure.

A note to C programmers: a Lisp list thus works as a linked list built up of cons cells. Because pointers in Lisp are implicit, we do not distinguish between a cons cell slot holding a value versus pointing to the value.

Because cons cells are so central to Lisp, we also have a word for an object which is not a cons cell. These objects are called atoms.

The read syntax and printed representation for lists are identical, and consist of a left parenthesis, an arbitrary number of elements, and a right parenthesis. Here are examples of lists:

(A 2 "A")            ; A list of three elements.
()                   ; A list of no elements (the empty list).
nil                  ; A list of no elements (the empty list).
("A ()")             ; A list of one element: the string "A ()".
(A ())               ; A list of two elements: A and the empty list.
(A nil)              ; Equivalent to the previous.
((A B C))            ; A list of one element
                     ;   (which is a list of three elements).

Upon reading, each object inside the parentheses becomes an element of the list. That is, a cons cell is made for each element. The CAR slot of the cons cell holds the element, and its CDR slot refers to the next cons cell of the list, which holds the next element in the list. The CDR slot of the last cons cell is set to hold nil.

The names CAR and CDR derive from the history of Lisp. The original Lisp implementation ran on an IBM 704 computer which divided words into two parts, the address and the decrement; CAR was an instruction to extract the contents of the address part of a register, and CDR an instruction to extract the contents of the decrement. By contrast, cons cells are named for the function cons that creates them, which in turn was named for its purpose, the construction of cells.

Next: Dotted Pair Notation, Up: Cons Cell and List Types [Contents][Index]

2.4.6.1 Drawing Lists as Box Diagrams ¶

A list can be illustrated by a diagram in which the cons cells are shown as pairs of boxes, like dominoes. (The Lisp reader cannot read such an illustration; unlike the textual notation, which can be understood by both humans and computers, the box illustrations can be understood only by humans.) This picture represents the three-element list (rose violet buttercup):

    --- ---      --- ---      --- ---
   |   |   |--> |   |   |--> |   |   |--> nil
    --- ---      --- ---      --- ---
     |            |            |
     |            |            |
      --> rose     --> violet   --> buttercup

In this diagram, each box represents a slot that can hold or refer to any Lisp object. Each pair of boxes represents a cons cell. Each arrow represents a reference to a Lisp object, either an atom or another cons cell.

In this example, the first box, which holds the CAR of the first cons cell, refers to or holds rose (a symbol). The second box, holding the CDR of the first cons cell, refers to the next pair of boxes, the second cons cell. The CAR of the second cons cell is violet, and its CDR is the third cons cell. The CDR of the third (and last) cons cell is nil.

Here is another diagram of the same list, (rose violet buttercup), sketched in a different manner:

 ---------------       ----------------       -------------------
| car   | cdr   |     | car    | cdr   |     | car       | cdr   |
| rose  |   o-------->| violet |   o-------->| buttercup |  nil  |
|       |       |     |        |       |     |           |       |
 ---------------       ----------------       -------------------

A list with no elements in it is the empty list; it is identical to the symbol nil. In other words, nil is both a symbol and a list.

Here is the list (A ()), or equivalently (A nil), depicted with boxes and arrows:

    --- ---      --- ---
   |   |   |--> |   |   |--> nil
    --- ---      --- ---
     |            |
     |            |
      --> A        --> nil

Here is a more complex illustration, showing the three-element list, ((pine needles) oak maple), the first element of which is a two-element list:

    --- ---      --- ---      --- ---
   |   |   |--> |   |   |--> |   |   |--> nil
    --- ---      --- ---      --- ---
     |            |            |
     |            |            |
     |             --> oak      --> maple
     |
     |     --- ---      --- ---
      --> |   |   |--> |   |   |--> nil
           --- ---      --- ---
            |            |
            |            |
             --> pine     --> needles

The same list represented in the second box notation looks like this:

 --------------       --------------       --------------
| car   | cdr  |     | car   | cdr  |     | car   | cdr  |
|   o   |   o------->| oak   |   o------->| maple |  nil |
|   |   |      |     |       |      |     |       |      |
 -- | ---------       --------------       --------------
    |
    |
    |        --------------       ----------------
    |       | car   | cdr  |     | car     | cdr  |
     ------>| pine  |   o------->| needles |  nil |
            |       |      |     |         |      |
             --------------       ----------------

Next: Association List Type, Previous: Drawing Lists as Box Diagrams, Up: Cons Cell and List Types [Contents][Index]

2.4.6.2 Dotted Pair Notation ¶

Dotted pair notation is a general syntax for cons cells that represents the CAR and CDR explicitly. In this syntax, (a . b) stands for a cons cell whose CAR is the object a and whose CDR is the object b. Dotted pair notation is more general than list syntax because the CDR does not have to be a list. However, it is more cumbersome in cases where list syntax would work. In dotted pair notation, the list ‘(1 2 3)’ is written as ‘(1 . (2 . (3 . nil)))’. For nil-terminated lists, you can use either notation, but list notation is usually clearer and more convenient. When printing a list, the dotted pair notation is only used if the CDR of a cons cell is not a list.

Here’s an example using boxes to illustrate dotted pair notation. This example shows the pair (rose . violet):

    --- ---
   |   |   |--> violet
    --- ---
     |
     |
      --> rose

You can combine dotted pair notation with list notation to represent conveniently a chain of cons cells with a non-nil final CDR. You write a dot after the last element of the list, followed by the CDR of the final cons cell. For example, (rose violet . buttercup) is equivalent to (rose . (violet . buttercup)). The object looks like this:

    --- ---      --- ---
   |   |   |--> |   |   |--> buttercup
    --- ---      --- ---
     |            |
     |            |
      --> rose     --> violet

The syntax (rose . violet . buttercup) is invalid because there is nothing that it could mean. If anything, it would say to put buttercup in the CDR of a cons cell whose CDR is already used for violet.

The list (rose violet) is equivalent to (rose . (violet)), and looks like this:

    --- ---      --- ---
   |   |   |--> |   |   |--> nil
    --- ---      --- ---
     |            |
     |            |
      --> rose     --> violet

Similarly, the three-element list (rose violet buttercup) is equivalent to (rose . (violet . (buttercup))). It looks like this:

    --- ---      --- ---      --- ---
   |   |   |--> |   |   |--> |   |   |--> nil
    --- ---      --- ---      --- ---
     |            |            |
     |            |            |
      --> rose     --> violet   --> buttercup

Previous: Dotted Pair Notation, Up: Cons Cell and List Types [Contents][Index]

2.4.6.3 Association List Type ¶

An association list or alist is a specially-constructed list whose elements are cons cells. In each element, the CAR is considered a key, and the CDR is considered an associated value. (In some cases, the associated value is stored in the CAR of the CDR.) Association lists are often used as stacks, since it is easy to add or remove associations at the front of the list.

For example,

(setq alist-of-colors
      '((rose . red) (lily . white) (buttercup . yellow)))

sets the variable alist-of-colors to an alist of three elements. In the first element, rose is the key and red is the value.

See Association Lists, for a further explanation of alists and for functions that work on alists. See Hash Tables, for another kind of lookup table, which is much faster for handling a large number of keys.

Next: String Type, Previous: Cons Cell and List Types, Up: Programming Types [Contents][Index]

2.4.7 Array Type ¶

An array is composed of an arbitrary number of slots for holding or referring to other Lisp objects, arranged in a contiguous block of memory. Accessing any element of an array takes approximately the same amount of time. In contrast, accessing an element of a list requires time proportional to the position of the element in the list. (Elements at the end of a list take longer to access than elements at the beginning of a list.)

Emacs defines four types of array: strings, vectors, bool-vectors, and char-tables.

A string is an array of characters and a vector is an array of arbitrary objects. A bool-vector can hold only t or nil. These kinds of array may have any length up to the largest fixnum, subject to system architecture limits and available memory. Char-tables are sparse arrays indexed by any valid character code; they can hold arbitrary objects.

The first element of an array has index zero, the second element has index 1, and so on. This is called zero-origin indexing. For example, an array of four elements has indices 0, 1, 2, and 3. The largest possible index value is one less than the length of the array. Once an array is created, its length is fixed.

All Emacs Lisp arrays are one-dimensional. (Most other programming languages support multidimensional arrays, but they are not essential; you can get the same effect with nested one-dimensional arrays.) Each type of array has its own read syntax; see the following sections for details.

The array type is a subset of the sequence type, and contains the string type, the vector type, the bool-vector type, and the char-table type.

Next: Vector Type, Previous: Array Type, Up: Programming Types [Contents][Index]

2.4.8 String Type ¶

A string is an array of characters. Strings are used for many purposes in Emacs, as can be expected in a text editor; for example, as the names of Lisp symbols, as messages for the user, and to represent text extracted from buffers. Strings in Lisp are constants: evaluation of a string returns the same string.

See Strings and Characters, for functions that operate on strings.

Next: Non-ASCII Characters in Strings, Up: String Type [Contents][Index]

2.4.8.1 Syntax for Strings ¶

The read syntax for a string is a double-quote, an arbitrary number of characters, and another double-quote, "like this". To include a double-quote in a string, precede it with a backslash; thus, "\"" is a string containing just one double-quote character. Likewise, you can include a backslash by preceding it with another backslash, like this: "this \\ is a single embedded backslash".

Since a string is an array of characters, you can specify the string characters using the read syntax of characters, but without the leading question mark. This is useful for including in string constants characters that don’t stand for themselves. Thus, control characters can be specified as escape sequences that start with a backslash; for example, "foo\r" yields ‘foo’ followed by the carriage return character. See Basic Char Syntax, for escape sequences of other control characters. Similarly, you can use the special read syntax for control characters (see Control-Character Syntax), as in "foo\^Ibar", which produces a tab character embedded within a string. You can also use the escape sequences for non-ASCII characters described in General Escape Syntax, as in "\N{LATIN SMALL LETTER A WITH GRAVE}" and "\u00e0" (however, see a caveat with non-ASCII characters in Non-ASCII Characters in Strings).

The newline character is not special in the read syntax for strings; if you write a new line between the double-quotes, it becomes a character in the string. But an escaped newline—one that is preceded by ‘\’—does not become part of the string; i.e., the Lisp reader ignores an escaped newline while reading a string. An escaped space ‘\ ’ is likewise ignored.

"It is useful to include newlines
in documentation strings,
but the newline is \
ignored if escaped."
     ⇒ "It is useful to include newlines
in documentation strings,
but the newline is ignored if escaped."

Next: Nonprinting Characters in Strings, Previous: Syntax for Strings, Up: String Type [Contents][Index]

2.4.8.2 Non-ASCII Characters in Strings ¶

There are two text representations for non-ASCII characters in Emacs strings: multibyte and unibyte (see Text Representations). Roughly speaking, unibyte strings store raw bytes, while multibyte strings store human-readable text. Each character in a unibyte string is a byte, i.e., its value is between 0 and 255. By contrast, each character in a multibyte string may have a value between 0 to 4194303 (see Character Type). In both cases, characters above 127 are non-ASCII.

You can include a non-ASCII character in a string constant by writing it literally. If the string constant is read from a multibyte source, such as a multibyte buffer or string, or a file that would be visited as multibyte, then Emacs reads each non-ASCII character as a multibyte character and automatically makes the string a multibyte string. If the string constant is read from a unibyte source, then Emacs reads the non-ASCII character as unibyte, and makes the string unibyte.

Instead of writing a character literally into a multibyte string, you can write it as its character code using an escape sequence. See General Escape Syntax, for details about escape sequences.

If you use any Unicode-style escape sequence ‘\uNNNN’ or ‘\U00NNNNNN’ in a string constant (even for an ASCII character), Emacs automatically assumes that it is multibyte.

You can also use hexadecimal escape sequences (‘\xn’) and octal escape sequences (‘\n’) in string constants. But beware: If a string constant contains octal escape sequences or one- or two-digit hexadecimal escape sequences, and these escape sequences all specify unibyte characters (i.e., codepoints less than 256), and there are no other literal non-ASCII characters or Unicode-style escape sequences in the string, then Emacs automatically assumes that it is a unibyte string. That is to say, it assumes that all non-ASCII characters occurring in the string are 8-bit raw bytes.

In hexadecimal and octal escape sequences, the escaped character code may contain a variable number of digits, so the first subsequent character which is not a valid hexadecimal or octal digit terminates the escape sequence. If the next character in a string could be interpreted as a hexadecimal or octal digit, write ‘\ ’ (backslash and space) to terminate the escape sequence. For example, ‘\xe0\ ’ represents one character, ‘a’ with grave accent. ‘\ ’ in a string constant is just like backslash-newline; it does not contribute any character to the string, but it does terminate any preceding hex escape.

Next: Text Properties in Strings, Previous: Non-ASCII Characters in Strings, Up: String Type [Contents][Index]

2.4.8.3 Nonprinting Characters in Strings ¶

You can use the same backslash escape-sequences in a string constant as in character literals (but do not use the question mark that begins a character constant). For example, you can write a string containing the nonprinting characters tab and C-a, with commas and spaces between them, like this: "\t, \C-a". See Character Type, and its subsections for a description of the various kinds of read syntax for characters.

However, not all of the characters you can write with backslash escape-sequences are valid in strings. The only control characters that a string can hold are the ASCII control characters. Strings do not distinguish case in ASCII control characters.

Properly speaking, strings cannot hold meta characters; but when a string is to be used as a key sequence, there is a special convention that provides a way to represent meta versions of ASCII characters in a string. If you use the ‘\M-’ syntax to indicate a meta character in a string constant, this sets the 2**7 bit of the character in the string. If the string is used in define-key or lookup-key, this numeric code is translated into the equivalent meta character. See Character Type.

Strings cannot hold characters that have the hyper, super, or alt modifiers.

Previous: Nonprinting Characters in Strings, Up: String Type [Contents][Index]

2.4.8.4 Text Properties in Strings ¶

A string can hold properties for the characters it contains, in addition to the characters themselves. This enables programs that copy text between strings and buffers to copy the text’s properties with no special effort. See Text Properties, for an explanation of what text properties mean. Strings with text properties use a special read and print syntax:

#("characters" property-data...)

where property-data consists of zero or more elements, in groups of three as follows:

beg end plist

The elements beg and end are integers, and together specify a range of indices in the string; plist is the property list for that range. For example,

#("foo bar" 0 3 (face bold) 3 4 nil 4 7 (face italic))

represents a string whose textual contents are ‘foo bar’, in which the first three characters have a face property with value bold, and the last three have a face property with value italic. (The fourth character has no text properties, so its property list is nil. It is not actually necessary to mention ranges with nil as the property list, since any characters not mentioned in any range will default to having no properties.)

Next: Char-Table Type, Previous: String Type, Up: Programming Types [Contents][Index]

2.4.9 Vector Type ¶

A vector is a one-dimensional array of elements of any type. It takes a constant amount of time to access any element of a vector. (In a list, the access time of an element is proportional to the distance of the element from the beginning of the list.)

The printed representation of a vector consists of a left square bracket, the elements, and a right square bracket. This is also the read syntax. Like numbers and strings, vectors are considered constants for evaluation.

[1 "two" (three)]      ; A vector of three elements.
     ⇒ [1 "two" (three)]

See Vectors, for functions that work with vectors.

Next: Bool-Vector Type, Previous: Vector Type, Up: Programming Types [Contents][Index]

2.4.10 Char-Table Type ¶

A char-table is a one-dimensional array of elements of any type, indexed by character codes. Char-tables have certain extra features to make them more useful for many jobs that involve assigning information to character codes—for example, a char-table can have a parent to inherit from, a default value, and a small number of extra slots to use for special purposes. A char-table can also specify a single value for a whole character set.

The printed representation of a char-table is like a vector except that there is an extra ‘#^’ at the beginning.¹

See Char-Tables, for special functions to operate on char-tables. Uses of char-tables include:

Case tables (see The Case Table).
Character category tables (see Categories).
Display tables (see Display Tables).
Syntax tables (see Syntax Tables).

Next: Hash Table Type, Previous: Char-Table Type, Up: Programming Types [Contents][Index]

2.4.11 Bool-Vector Type ¶

A bool-vector is a one-dimensional array whose elements must be t or nil.

The printed representation of a bool-vector is like a string, except that it begins with ‘#&’ followed by the length. The string constant that follows actually specifies the contents of the bool-vector as a bitmap—each character in the string contains 8 bits, which specify the next 8 elements of the bool-vector (1 stands for t, and 0 for nil). The least significant bits of the character correspond to the lowest indices in the bool-vector.

(make-bool-vector 3 t)
     ⇒ #&3"^G"
(make-bool-vector 3 nil)
     ⇒ #&3"^@"

These results make sense, because the binary code for ‘C-g’ is 111 and ‘C-@’ is the character with code 0.

If the length is not a multiple of 8, the printed representation shows extra elements, but these extras really make no difference. For instance, in the next example, the two bool-vectors are equal, because only the first 3 bits are used:

(equal #&3"\377" #&3"\007")
     ⇒ t

Next: Function Type, Previous: Bool-Vector Type, Up: Programming Types [Contents][Index]

2.4.12 Hash Table Type ¶

A hash table is a very fast kind of lookup table, somewhat like an alist in that it maps keys to corresponding values, but much faster. The printed representation of a hash table specifies its properties and contents, like this:

(make-hash-table)
     ⇒ #s(hash-table)

See Hash Tables, for more information about hash tables.

Next: Macro Type, Previous: Hash Table Type, Up: Programming Types [Contents][Index]

2.4.13 Function Type ¶

Lisp functions are executable code, just like functions in other programming languages. In Lisp, unlike most languages, functions are also Lisp objects. A non-compiled function in Lisp is a lambda expression: that is, a list whose first element is the symbol lambda (see Lambda Expressions).

In most programming languages, it is impossible to have a function without a name. In Lisp, a function has no intrinsic name. A lambda expression can be called as a function even though it has no name; to emphasize this, we also call it an anonymous function (see Anonymous Functions). A named function in Lisp is just a symbol with a valid function in its function cell (see Defining Functions).

Most of the time, functions are called when their names are written in Lisp expressions in Lisp programs. However, you can construct or obtain a function object at run time and then call it with the primitive functions funcall and apply. See Calling Functions.

Next: Primitive Function Type, Previous: Function Type, Up: Programming Types [Contents][Index]

2.4.14 Macro Type ¶

A Lisp macro is a user-defined construct that extends the Lisp language. It is represented as an object much like a function, but with different argument-passing semantics. A Lisp macro has the form of a list whose first element is the symbol macro and whose CDR is a Lisp function object, including the lambda symbol.

Lisp macro objects are usually defined with the built-in defmacro macro, but any list that begins with macro is a macro as far as Emacs is concerned. See Macros, for an explanation of how to write a macro.

Warning: Lisp macros and keyboard macros (see Keyboard Macros) are entirely different things. When we use the word “macro” without qualification, we mean a Lisp macro, not a keyboard macro.

Next: Closure Function Type, Previous: Macro Type, Up: Programming Types [Contents][Index]

2.4.15 Primitive Function Type ¶

A primitive function is a function callable from Lisp but written in the C programming language. Primitive functions are also called subrs or built-in functions. (The word “subr” is derived from “subroutine”.) Most primitive functions evaluate all their arguments when they are called. A primitive function that does not evaluate all its arguments is called a special form (see Special Forms).

It does not matter to the caller of a function whether the function is primitive. However, this does matter if you try to redefine a primitive with a function written in Lisp. The reason is that the primitive function may be called directly from C code. Calls to the redefined function from Lisp will use the new definition, but calls from C code may still use the built-in definition. Therefore, we discourage redefinition of primitive functions.

The term function refers to all Emacs functions, whether written in Lisp or C. See Function Type, for information about the functions written in Lisp.

Primitive functions have no read syntax and print in hash notation with the name of the subroutine.

(symbol-function 'car)          ; Access the function cell
                                ;   of the symbol.
     ⇒ #<subr car>
(subrp (symbol-function 'car))  ; Is this a primitive function?
     ⇒ t                       ; Yes.

Next: Record Type, Previous: Primitive Function Type, Up: Programming Types [Contents][Index]

2.4.16 Closure Function Type ¶

Closures are function objects produced when turning a function definition into a function value. Closures are used both for byte-compiled Lisp functions as well as for interpreted Lisp functions. Closures can be produced by byte-compiling Lisp code (see Byte Compilation) or simply by evaluating a lambda expression without compiling it, resulting in an interpreted function. Internally, a closure is much like a vector; however, the evaluator handles this data type specially when it appears in a function call. See Closure Function Objects.

The printed representation and read syntax for a byte-code function object is like that for a vector, with an additional ‘#’ before the opening ‘[’. When printed for human consumption, it is printed as a special kind of list with an additional ‘#f’ before the opening ‘(’.

Next: Type Descriptors, Previous: Closure Function Type, Up: Programming Types [Contents][Index]

2.4.17 Record Type ¶

A record is much like a vector. However, the first element is used to hold its type as returned by type-of. The purpose of records is to allow programmers to create objects with new types that are not built into Emacs.

See Records, for functions that work with records.

Next: Type Specifiers, Previous: Record Type, Up: Programming Types [Contents][Index]

2.4.18 Type Descriptors ¶

A type descriptor is a record which holds information about a type. The first slot in the record must be a symbol naming the type, and type-of relies on this to return the type of record objects. No other type descriptor slot is used by Emacs; they are free for use by Lisp extensions.

An example of a type descriptor is any instance of cl-structure-class.

Next: Autoload Type, Previous: Type Descriptors, Up: Programming Types [Contents][Index]

2.4.19 Type Specifiers ¶

A type specifier is an expression that denotes a type. A type represents a set of possible values. Type specifiers can be classified into primitive types and compound types.

Type specifiers are used for several purposes, including: documenting function interfaces through declarations (see The declare Form), specifying structure slot types (see Structures in Common Lisp Extensions for GNU Emacs Lisp), performing type checks with cl-the (see Declarations in Common Lisp Extensions for GNU Emacs Lisp), and aiding the native compiler (see Compilation of Lisp to Native Code) in optimizing code generation and inferring function signatures.

Primitive type specifiers

Primitive types specifiers are the basic types (i.e. not composed by other type specifiers).

Built-in primitive types (like integer, float, string etc.) are listed in Type Hierarchy of Emacs Lisp Objects.

Compound type specifiers

Compound types serve the purpose of defining more complex or precise type specifications by combining or modifying simpler types.

List of compound type specifiers:

(or type-1 … type-n)

The or type specifier describes a type that satisfies at least one of the given types.

(and type-1 … type-n)

Similarly the and type specifier describes a type that satisfies all of the given types.

(not type)

The not type specifier defines any type except the specified one.

(member value-1 … value-n)

The member type specifier allows to specify a type that includes only the explicitly listed values.

(function (arg-1-type … arg-n-type) return-type) ¶

The function type specifier is used to describe the argument types and the return type of a function. Argument types can be interleaved with symbols &optional and &rest to match the function’s arguments (see Features of Argument Lists).

The following type specifier represents a function whose first parameter is of type symbol, the second optional parameter is of type float, and which returns an integer:

 (function (symbol &optional float) integer)

(integer lower-bound upper-bound)

The integer type specifier can also be used as a compound type specifier to define a subset of integer values by specifying a range. This allows to precisely control which integers are valid for a given type.

lower-bound is the minimum integer value in the range and upper-bound the maximum. You can use * instead of the lower or upper bound to indicate no limit.

The following represents all integers from -10 to 10:

(integer -10 10)

The following represents the single value of 10:

(integer 10 10)

The following represents all the integers from negative infinity to 10:

(integer * 10)

Next: Finalizer Type, Previous: Type Specifiers, Up: Programming Types [Contents][Index]

2.4.20 Autoload Type ¶

An autoload object is a list whose first element is the symbol autoload. It is stored as the function definition of a symbol, where it serves as a placeholder for the real definition. The autoload object says that the real definition is found in a file of Lisp code that should be loaded when necessary. It contains the name of the file, plus some other information about the real definition.

After the file has been loaded, the symbol should have a new function definition that is not an autoload object. The new definition is then called as if it had been there to begin with. From the user’s point of view, the function call works as expected, using the function definition in the loaded file.

An autoload object is usually created with the function autoload, which stores the object in the function cell of a symbol. See Autoload, for more details.

Previous: Autoload Type, Up: Programming Types [Contents][Index]

2.4.21 Finalizer Type ¶

A finalizer object helps Lisp code clean up after objects that are no longer needed. A finalizer holds a Lisp function object. When a finalizer object becomes unreachable after a garbage collection pass, Emacs calls the finalizer’s associated function object. When deciding whether a finalizer is reachable, Emacs does not count references from finalizer objects themselves, allowing you to use finalizers without having to worry about accidentally capturing references to finalized objects themselves.

Errors in finalizers are printed to *Messages*. Emacs runs a given finalizer object’s associated function exactly once, even if that function fails.

Function: make-finalizer function ¶: Make a finalizer that will run function. function will be called after garbage collection when the returned finalizer object becomes unreachable. If the finalizer object is reachable only through references from finalizer objects, it does not count as reachable for the purpose of deciding whether to run function. function will be run once per finalizer object.

Next: Read Syntax for Circular Objects, Previous: Programming Types, Up: Lisp Data Types [Contents][Index]

2.5 Editing Types ¶

The types in the previous section are used for general programming purposes, and most of them are common to most Lisp dialects. Emacs Lisp provides several additional data types for purposes connected with editing.

Next: Marker Type, Up: Editing Types [Contents][Index]

2.5.1 Buffer Type ¶

A buffer is an object that holds text that can be edited (see Buffers). Most buffers hold the contents of a disk file (see Files) so they can be edited, but some are used for other purposes. Most buffers are also meant to be seen by the user, and therefore displayed, at some time, in a window (see Windows). But a buffer need not be displayed in any window. Each buffer has a designated position called point (see Positions); most editing commands act on the contents of the current buffer in the neighborhood of point. At any time, one buffer is the current buffer.

The contents of a buffer are much like a string, but buffers are not used like strings in Emacs Lisp, and the available operations are different. For example, you can insert text efficiently into an existing buffer, altering the buffer’s contents, whereas inserting text into a string requires concatenating substrings, and the result is an entirely new string object.

Many of the standard Emacs functions manipulate or test the characters in the current buffer; a whole chapter in this manual is devoted to describing these functions (see Text).

Several other data structures are associated with each buffer:

a local syntax table (see Syntax Tables);
a local keymap (see Keymaps); and,
a list of buffer-local variable bindings (see Buffer-Local Variables).
overlays (see Overlays).
text properties for the text in the buffer (see Text Properties).

The local keymap and variable list contain entries that individually override global bindings or values. These are used to customize the behavior of programs in different buffers, without actually changing the programs.

A buffer may be indirect, which means it shares the text of another buffer, but presents it differently. See Indirect Buffers.

Buffers have no read syntax. They print in hash notation, showing the buffer name.

(current-buffer)
     ⇒ #<buffer objects.texi>

Next: Window Type, Previous: Buffer Type, Up: Editing Types [Contents][Index]

2.5.2 Marker Type ¶

A marker denotes a position in a specific buffer. Markers therefore have two components: one for the buffer, and one for the position. Changes in the buffer’s text automatically relocate the position value as necessary to ensure that the marker always points between the same two characters in the buffer.

Markers have no read syntax. They print in hash notation, giving the current character position and the name of the buffer.

(point-marker)
     ⇒ #<marker at 10779 in objects.texi>

See Markers, for information on how to test, create, copy, and move markers.

Next: Frame Type, Previous: Marker Type, Up: Editing Types [Contents][Index]

2.5.3 Window Type ¶

A window describes the portion of the screen that Emacs uses to display buffers. Every live window (see Basic Concepts of Emacs Windows) has one associated buffer, whose contents appear in that window. By contrast, a given buffer may appear in one window, no window, or several windows. Windows are grouped on the screen into frames; each window belongs to one and only one frame. See Frame Type.

Though many windows may exist simultaneously, at any time one window is designated the selected window (see Selecting Windows). This is the window where the cursor is (usually) displayed when Emacs is ready for a command. The selected window usually displays the current buffer (see The Current Buffer), but this is not necessarily the case.

Windows have no read syntax. They print in hash notation, giving the window number and the name of the buffer being displayed. The window numbers exist to identify windows uniquely, since the buffer displayed in any given window can change frequently.

(selected-window)
     ⇒ #<window 1 on objects.texi>

See Windows, for a description of the functions that work on windows.

Next: Terminal Type, Previous: Window Type, Up: Editing Types [Contents][Index]

2.5.4 Frame Type ¶

A frame is a screen area that contains one or more Emacs windows; we also use the term “frame” to refer to the Lisp object that Emacs uses to refer to the screen area.

Frames have no read syntax. They print in hash notation, giving the frame’s title, plus its address in core (useful to identify the frame uniquely).

(selected-frame)
     ⇒ #<frame emacs@psilocin.gnu.org 0xdac80>

See Frames, for a description of the functions that work on frames.

Next: Window Configuration Type, Previous: Frame Type, Up: Editing Types [Contents][Index]

2.5.5 Terminal Type ¶

A terminal is a device capable of displaying one or more Emacs frames (see Frame Type).

Terminals have no read syntax. They print in hash notation giving the terminal’s ordinal number and its TTY device file name.

(get-device-terminal nil)
     ⇒ #<terminal 1 on /dev/tty>

Next: Frame Configuration Type, Previous: Terminal Type, Up: Editing Types [Contents][Index]

2.5.6 Window Configuration Type ¶

A window configuration stores information about the positions, sizes, and contents of the windows in a frame, so you can recreate the same arrangement of windows later.

Window configurations do not have a read syntax; their print syntax looks like ‘#<window-configuration>’. See Window Configurations, for a description of several functions related to window configurations.

Next: Process Type, Previous: Window Configuration Type, Up: Editing Types [Contents][Index]

2.5.7 Frame Configuration Type ¶

A frame configuration stores information about the positions, sizes, and contents of the windows in all frames. It is not a primitive type—it is actually a list whose CAR is frame-configuration and whose CDR is an alist. Each alist element describes one frame, which appears as the CAR of that element.

See Frame Configurations, for a description of several functions related to frame configurations.

Next: Thread Type, Previous: Frame Configuration Type, Up: Editing Types [Contents][Index]

2.5.8 Process Type ¶

The word process usually means a running program. Emacs itself runs in a process of this sort. However, in Emacs Lisp, a process is a Lisp object that designates a subprocess created by the Emacs process. Programs such as shells, GDB, ftp, and compilers, running in subprocesses of Emacs, extend the capabilities of Emacs. An Emacs subprocess takes textual input from Emacs and returns textual output to Emacs for further manipulation. Emacs can also send signals to the subprocess.

Process objects have no read syntax. They print in hash notation, giving the name of the process:

(process-list)
     ⇒ (#<process shell>)

See Processes, for information about functions that create, delete, return information about, send input or signals to, and receive output from processes.

Next: Mutex Type, Previous: Process Type, Up: Editing Types [Contents][Index]

2.5.9 Thread Type ¶

A thread in Emacs represents a separate thread of Emacs Lisp execution. It runs its own Lisp program, has its own current buffer, and can have subprocesses locked to it, i.e. subprocesses whose output only this thread can accept. See Threads.

Thread objects have no read syntax. They print in hash notation, giving the name of the thread (if it has been given a name) or its address in core:

(all-threads)
    ⇒ (#<thread 0176fc40>)

Next: Condition Variable Type, Previous: Thread Type, Up: Editing Types [Contents][Index]

2.5.10 Mutex Type ¶

A mutex is an exclusive lock that threads can own and disown, in order to synchronize between them. See Mutexes.

Mutex objects have no read syntax. They print in hash notation, giving the name of the mutex (if it has been given a name) or its address in core:

(make-mutex "my-mutex")
    ⇒ #<mutex my-mutex>
(make-mutex)
    ⇒ #<mutex 01c7e4e0>

Next: Stream Type, Previous: Mutex Type, Up: Editing Types [Contents][Index]

2.5.11 Condition Variable Type ¶

A condition variable is a device for a more complex thread synchronization than the one supported by a mutex. A thread can wait on a condition variable, to be woken up when some other thread notifies the condition.

Condition variable objects have no read syntax. They print in hash notation, giving the name of the condition variable (if it has been given a name) or its address in core:

(make-condition-variable (make-mutex))
    ⇒ #<condvar 01c45ae8>

Next: Keymap Type, Previous: Condition Variable Type, Up: Editing Types [Contents][Index]

2.5.12 Stream Type ¶

A stream is an object that can be used as a source or sink for characters—either to supply characters for input or to accept them as output. Many different types can be used this way: markers, buffers, strings, and functions. Most often, input streams (character sources) obtain characters from the keyboard, a buffer, or a file, and output streams (character sinks) send characters to a buffer, such as a *Help* buffer, or to the echo area.

The object nil, in addition to its other meanings, may be used as a stream. It stands for the value of the variable standard-input or standard-output. Also, the object t as a stream specifies input using the minibuffer (see Minibuffers) or output in the echo area (see The Echo Area).

Streams have no special printed representation or read syntax, and print as whatever primitive type they are.

See Reading and Printing Lisp Objects, for a description of functions related to streams, including parsing and printing functions.

Next: Overlay Type, Previous: Stream Type, Up: Editing Types [Contents][Index]

2.5.13 Keymap Type ¶

A keymap maps keys typed by the user to commands. This mapping controls how the user’s command input is executed. A keymap is actually a list whose CAR is the symbol keymap.

See Keymaps, for information about creating keymaps, handling prefix keys, local as well as global keymaps, and changing key bindings.

Next: Font Type, Previous: Keymap Type, Up: Editing Types [Contents][Index]

2.5.14 Overlay Type ¶

An overlay specifies properties that apply to a part of a buffer. Each overlay applies to a specified range of the buffer, and contains a property list (a list whose elements are alternating property names and values). Overlay properties are used to present parts of the buffer temporarily in a different display style. Overlays have no read syntax, and print in hash notation, giving the buffer name and range of positions.

See Overlays, for information on how you can create and use overlays.

Next: Xwidget Type, Previous: Overlay Type, Up: Editing Types [Contents][Index]

2.5.15 Font Type ¶

A font specifies how to display text on a graphical terminal. There are actually three separate font types—font objects, font specs, and font entities—each of which has slightly different properties. None of them have a read syntax; their print syntax looks like ‘#<font-object>’, ‘#<font-spec>’, and ‘#<font-entity>’ respectively. See Low-Level Font Representation, for a description of these Lisp objects.

Next: Type Predicates, Previous: Editing Types, Up: Lisp Data Types [Contents][Index]

2.6 Read Syntax for Circular Objects ¶

To represent shared or circular structures within a complex of Lisp objects, you can use the reader constructs ‘#n=’ and ‘#n#’.

Use #n= before an object to label it for later reference; subsequently, you can use #n# to refer the same object in another place. Here, n is some integer. For example, here is how to make a list in which the first element recurs as the third element:

(#1=(a) b #1#)

This differs from ordinary syntax such as this

((a) b (a))

which would result in a list whose first and third elements look alike but are not the same Lisp object. This shows the difference:

(prog1 nil
  (setq x '(#1=(a) b #1#)))
(eq (nth 0 x) (nth 2 x))
     ⇒ t
(setq x '((a) b (a)))
(eq (nth 0 x) (nth 2 x))
     ⇒ nil

You can also use the same syntax to make a circular structure, which appears as an element within itself. Here is an example:

#1=(a #1#)

This makes a list whose second element is the list itself. Here’s how you can see that it really works:

(prog1 nil
  (setq x '#1=(a #1#)))
(eq x (cadr x))
     ⇒ t

The Lisp printer can produce this syntax to record circular and shared structure in a Lisp object, if you bind the variable print-circle to a non-nil value. See Variables Affecting Output.

Next: Equality Predicates, Previous: Read Syntax for Circular Objects, Up: Lisp Data Types [Contents][Index]

2.7 Type Predicates ¶

The Emacs Lisp interpreter itself does not perform type checking on the actual arguments passed to functions when they are called. It could not do so, since function arguments in Lisp do not have declared data types, as they do in other programming languages. It is therefore up to the individual function to test whether each actual argument belongs to a type that the function can use.

All built-in functions do check the types of their actual arguments when appropriate, and signal a wrong-type-argument error if an argument is of the wrong type. For example, here is what happens if you pass an argument to + that it cannot handle:

(+ 2 'a)
     error→ Wrong type argument: number-or-marker-p, a

If you want your program to handle different types differently, you must do explicit type checking. The most common way to check the type of an object is to call a type predicate function. Emacs has a type predicate for each type, as well as some predicates for combinations of types.

A type predicate function takes one argument; it returns t if the argument belongs to the appropriate type, and nil otherwise. Following a general Lisp convention for predicate functions, most type predicates’ names end with ‘p’.

Here is an example which uses the predicates listp to check for a list and symbolp to check for a symbol.

(defun add-on (x)
  (cond ((symbolp x)
         ;; If X is a symbol, put it on LIST.
         (setq list (cons x list)))
        ((listp x)
         ;; If X is a list, add its elements to LIST.
         (setq list (append x list)))
        (t
         ;; We handle only symbols and lists.
         (error "Invalid argument %s in add-on" x))))

Here is a table of predefined type predicates, in alphabetical order, with references to further information.

atom: See atom.
arrayp: See arrayp.
bignump: See bignump.
bool-vector-p: See bool-vector-p.
booleanp: See booleanp.
bufferp: See bufferp.
byte-code-function-p: See byte-code-function-p.
case-table-p: See case-table-p.
char-or-string-p: See char-or-string-p.
char-table-p: See char-table-p.
closurep: See closurep.
commandp: See commandp.
compiled-function-p: See compiled-function-p.
condition-variable-p: See condition-variable-p.
consp: See consp.
custom-variable-p: See custom-variable-p.
fixnump: See fixnump.
floatp: See floatp.
fontp: See Low-Level Font Representation.
frame-configuration-p: See frame-configuration-p.
frame-live-p: See frame-live-p.
framep: See framep.
functionp: See functionp.
hash-table-p: See hash-table-p.
integer-or-marker-p: See integer-or-marker-p.
integerp: See integerp.
interpreted-function-p: See interpreted-function-p.
keymapp: See keymapp.
keywordp: See Variables that Never Change.
listp: See listp.
markerp: See markerp.
mutexp: See mutexp.
nlistp: See nlistp.
number-or-marker-p: See number-or-marker-p.
numberp: See numberp.
obarrayp: See obarrayp.
overlayp: See overlayp.
processp: See processp.
recordp: See recordp.
sequencep: See sequencep.
string-or-null-p: See string-or-null-p.
stringp: See stringp.
subrp: See subrp.
symbolp: See symbolp.
syntax-table-p: See syntax-table-p.
threadp: See threadp.
vectorp: See vectorp.
wholenump: See wholenump.
window-configuration-p: See window-configuration-p.
window-live-p: See window-live-p.
windowp: See windowp.

The most general way to check the type of an object is to call the function type-of. Recall that each object belongs to one and only one primitive type; type-of tells you which one (see Lisp Data Types). But type-of knows nothing about non-primitive types. In most cases, it is preferable to use type predicates than type-of.

Function: type-of object ¶

This function returns a symbol naming the primitive type of object. The value is one of the symbols bool-vector, buffer, char-table, compiled-function, condition-variable, cons, finalizer, float, font-entity, font-object, font-spec, frame, hash-table, integer, marker, mutex, obarray, overlay, process, string, subr, symbol, thread, vector, window, or window-configuration. However, if object is a record, the type specified by its first slot is returned; Records.

(type-of 1)
     ⇒ integer

(type-of 'nil)
     ⇒ symbol
(type-of '())    ; () is nil.
     ⇒ symbol
(type-of '(x))
     ⇒ cons
(type-of (record 'foo))
     ⇒ foo

Function: cl-type-of object ¶

This function returns a symbol naming the type of object. It usually behaves like type-of, except that it guarantees to return the most precise type possible, which also implies that the specific type it returns may change depending on the Emacs version. For this reason, as a rule you should never compare its return value against some fixed set of types.

(cl-type-of 1)
     ⇒ fixnum

(cl-type-of 'nil)
     ⇒ null
(cl-type-of (record 'foo))
     ⇒ foo

Next: Mutability, Previous: Type Predicates, Up: Lisp Data Types [Contents][Index]

2.8 Equality Predicates ¶

Here we describe functions that test for equality between two objects. Other functions test equality of contents between objects of specific types, e.g., strings. For these predicates, see the appropriate chapter describing the data type.

Function: eq object1 object2 ¶

This function returns t if object1 and object2 are the same object, and nil otherwise.

If object1 and object2 are symbols with the same name, they are normally the same object—but see Creating and Interning Symbols for exceptions. For other non-numeric types (e.g., lists, vectors, strings), two arguments with the same contents or elements are not necessarily eq to each other: they are eq only if they are the same object, meaning that a change in the contents of one will be reflected by the same change in the contents of the other.

If object1 and object2 are numbers with differing types or values, then they cannot be the same object and eq returns nil. If they are fixnums with the same value, then they are the same object and eq returns t. If they were computed separately but happen to have the same value and the same non-fixnum numeric type, then they might or might not be the same object, and eq returns t or nil depending on whether the Lisp interpreter created one object or two.

If object1 or object2 is a symbol with position, eq regards it as its bare symbol when symbols-with-pos-enabled is non-nil (see Symbols with Position).

(eq 'abc 'abc)  ⇒ t
(eq 'abc 'ABC)  ⇒ nil
(eq ?A ?A)      ⇒ t
(eq 3 3)        ⇒ t

Equal non-fixnum numbers may or may not be the same object:

(eq 3.0 3.0)                    ⇒ t or nil
(eq (expt 10 50) (expt 10 50))  ⇒ t or nil

Newly created mutable objects are distinct:

(eq (list 1 2 3) (list 1 2 3))      ⇒ nil
(eq (point-marker) (point-marker))  ⇒ nil

Equal constants of other types may or may not be the same object:

(eq "abc" "abc")        ⇒ t or nil
(eq '(1 2 3) '(1 2 3))  ⇒ t or nil
(eq [1 2 3] [1 2 3])    ⇒ t or nil

unless they are the same literal constant:

(let ((x "abc"))    (eq x x))  ⇒ t
(let ((x '(1 2 3))) (eq x x))  ⇒ t
(let ((x [1 2 3]))  (eq x x))  ⇒ t

The make-symbol function returns an uninterned symbol, distinct from the symbol that is used if you write the name in a Lisp expression. Distinct symbols with the same name are not eq. See Creating and Interning Symbols.

(eq (make-symbol "foo") 'foo)
     ⇒ nil

The Emacs Lisp byte compiler may collapse identical literal objects, such as literal strings, into references to the same object, with the effect that the byte-compiled code will compare such objects as eq, while the interpreted version of the same code will not. Therefore, your code should never rely on objects with the same literal contents being either eq or not eq, it should instead use functions that compare object contents such as equal, described below. Similarly, your code should not modify literal objects (e.g., put text properties on literal strings), since doing that might affect other literal objects of the same contents, if the byte compiler collapses them.

Function: equal object1 object2 ¶

This function returns t if object1 and object2 have equal components, and nil otherwise. Whereas eq tests if its arguments are the same object, equal looks inside nonidentical arguments to see if their elements or contents are the same. So, if two objects are eq, they are equal, but the converse is not always true.

(equal 'foo 'foo)
     ⇒ t

(equal 456 456)
     ⇒ t

(equal "asdf" "asdf")
     ⇒ t

(equal '(1 (2 (3))) '(1 (2 (3))))
     ⇒ t

(equal [(1 2) 3] [(1 2) 3])
     ⇒ t

(equal (point-marker) (point-marker))
     ⇒ t

The equal function compares strings and bool-vectors by value. Numbers are compared by type and numeric value, using eql. Lists, cons cells, vectors, records, markers, char-tables, font objects, and function objects (closures)² are compared recursively by using equal on their constituent parts.

Comparison of strings is case-sensitive, but does not take account of text properties—it compares only the characters in the strings. See Text Properties. Use equal-including-properties to also compare text properties. For technical reasons, a unibyte string and a multibyte string are equal if and only if they contain the same sequence of character codes and all these codes are in the range 0 through 127 (ASCII).

(equal "asdf" "ASDF")
     ⇒ nil

If object1 or object2 contains symbols with position, equal treats them as if they were their bare symbols when symbols-with-pos-enabled is non-nil. Otherwise equal compares two symbols with position by comparing their components. See Symbols with Position.

Other objects are considered equal only if they are eq. For example, two distinct buffers are never considered equal, even if their textual contents are the same.

For equal, equality is defined recursively; for example, given two cons cells x and y, (equal x y) returns t if and only if both the expressions below return t:

(equal (car x) (car y))
(equal (cdr x) (cdr y))

Comparing very deeply nested objects may therefore cause deep recursion that leads to an error.

Function: equal-including-properties object1 object2 ¶

This function behaves like equal in all cases but also requires that for two strings to be equal, they have the same text properties.

(equal "asdf" (propertize "asdf" 'asdf t))
     ⇒ t

(equal-including-properties "asdf"
                            (propertize "asdf" 'asdf t))
     ⇒ nil

Next: Type Hierarchy of Emacs Lisp Objects, Previous: Equality Predicates, Up: Lisp Data Types [Contents][Index]

2.9 Mutability ¶

Some Lisp objects should never change. For example, the Lisp expression "aaa" yields a string, but you should not change its contents. And some objects cannot be changed; for example, although you can create a new number by calculating one, Lisp provides no operation to change the value of an existing number.

Other Lisp objects are mutable: it is safe to change their values via destructive operations involving side effects. For example, an existing marker can be changed by moving the marker to point to somewhere else.

Although numbers never change and all markers are mutable, some types have members some of which are mutable and others not. These types include conses, vectors, and strings. For example, although "cons" and (symbol-name 'cons) both yield strings that should not be changed, (copy-sequence "cons") and (make-string 3 ?a) both yield mutable strings that can be changed via later calls to aset.

A mutable object stops being mutable if it is part of an expression that is evaluated. For example:

(let* ((x (list 0.5))
       (y (eval (list 'quote x))))
  (setcar x 1.5) ;; The program should not do this.
  y)

Although the list (0.5) was mutable when it was created, it should not have been changed via setcar because it was given to eval. The reverse does not occur: an object that should not be changed never becomes mutable afterwards.

If a program attempts to change objects that should not be changed, the resulting behavior is undefined: the Lisp interpreter might signal an error, or it might crash or behave unpredictably in other ways.³

When similar constants occur as parts of a program, the Lisp interpreter might save time or space by reusing existing constants or their components. For example, (eq "abc" "abc") returns t if the interpreter creates only one instance of the string literal "abc", and returns nil if it creates two instances. Lisp programs should be written so that they work regardless of whether this optimization is in use.

Previous: Mutability, Up: Lisp Data Types [Contents][Index]

2.10 Type Hierarchy of Emacs Lisp Objects ¶

Lisp object types are organized in a hierarchy, which means that types can derive from other types. Objects of type B (which derives from type A) inherit all the characteristics of type A. This also means that every object of type B is at the same time an object of type A from which it derives.

Every type derives from type t.

New types can be defined by the user through defclass or cl-defstruct.

The Lisp Type Hierarchy for primitive types can be represented as follows:

elisp_type_hierarchy

For example type list derives from (is a special kind of) type sequence which itself derives from t.

Next: Strings and Characters, Previous: Lisp Data Types, Up: Emacs Lisp [Contents][Index]

3 Numbers ¶

GNU Emacs supports two numeric data types: integers and floating-point numbers. Integers are whole numbers such as −3, 0, 7, 13, and 511. Floating-point numbers are numbers with fractional parts, such as −4.5, 0.0, and 2.71828. They can also be expressed in exponential notation: ‘1.5e2’ is the same as ‘150.0’; here, ‘e2’ stands for ten to the second power, and that is multiplied by 1.5. Integer computations are exact. Floating-point computations often involve rounding errors, as the numbers have a fixed amount of precision.

Next: Floating-Point Basics, Up: Numbers [Contents][Index]

3.1 Integer Basics ¶

The Lisp reader reads an integer as a nonempty sequence of decimal digits with optional initial sign and optional final period.

 1               ; The integer 1.
 1.              ; The integer 1.
+1               ; Also the integer 1.
-1               ; The integer −1.
 0               ; The integer 0.
-0               ; The integer 0.

The syntax for integers in bases other than 10 consists of ‘#’ followed by a radix indication followed by one or more digits. The radix indications are ‘b’ for binary, ‘o’ for octal, ‘x’ for hex, and ‘radixr’ for radix radix. Thus, ‘#binteger’ reads integer in binary, and ‘#radixrinteger’ reads integer in radix radix. Allowed values of radix run from 2 to 36, and allowed digits are the first radix characters taken from ‘0’–‘9’, ‘A’–‘Z’. Letter case is ignored and there is no initial sign or final period. For example:

#b101100 ⇒ 44
#o54 ⇒ 44
#x2c ⇒ 44
#24r1k ⇒ 44

To understand how various functions work on integers, especially the bitwise operators (see Bitwise Operations on Integers), it is often helpful to view the numbers in their binary form.

In binary, the decimal integer 5 looks like this:

...000101

(The ellipsis ‘…’ stands for a conceptually infinite number of bits that match the leading bit; here, an infinite number of 0 bits. Later examples also use this ‘…’ notation.)

The integer −1 looks like this:

...111111

−1 is represented as all ones. (This is called two’s complement notation.)

Subtracting 4 from −1 returns the negative integer −5. In binary, the decimal integer 4 is 100. Consequently, −5 looks like this:

...111011

Many of the functions described in this chapter accept markers for arguments in place of numbers. (See Markers.) Since the actual arguments to such functions may be either numbers or markers, we often give these arguments the name number-or-marker. When the argument value is a marker, its position value is used and its buffer is ignored.

In Emacs Lisp, text characters are represented by integers. Any integer between zero and the value of (max-char), inclusive, is considered to be valid as a character. See Character Codes.

Integers in Emacs Lisp are not limited to the machine word size. Under the hood, though, there are two kinds of integers: smaller ones, called fixnums, and larger ones, called bignums. Although Emacs Lisp code ordinarily should not depend on whether an integer is a fixnum or a bignum, older Emacs versions support only fixnums, some functions in Emacs still accept only fixnums, and older Emacs Lisp code may have trouble when given bignums. For example, while older Emacs Lisp code could safely compare integers for numeric equality with eq, the presence of bignums means that equality predicates like eql and = should now be used to compare integers.

The range of values for bignums is limited by the amount of main memory, by machine characteristics such as the size of the word used to represent a bignum’s exponent, and by the integer-width variable. These limits are typically much more generous than the limits for fixnums. A bignum is never numerically equal to a fixnum; Emacs always represents an integer in fixnum range as a fixnum, not a bignum.

The range of values for a fixnum depends on the machine. The minimum range is −536,870,912 to 536,870,911 (30 bits; i.e., −2**29 to 2**29 − 1), but many machines provide a wider range.

Variable: most-positive-fixnum ¶: The value of this variable is the greatest “small” integer that Emacs Lisp can handle. Typical values are 2**29 − 1 on 32-bit and 2**61 − 1 on 64-bit platforms.

Variable: most-negative-fixnum ¶: The value of this variable is the numerically least “small” integer that Emacs Lisp can handle. It is negative. Typical values are −2**29 on 32-bit and −2**61 on 64-bit platforms.

Variable: integer-width ¶: The value of this variable is a nonnegative integer that controls whether Emacs signals a range error when a large integer would be calculated. Integers with absolute values less than 2**n, where n is this variable’s value, do not signal a range error. Attempts to create larger integers typically signal a range error, although there might be no signal if a larger integer can be created cheaply. Setting this variable to a large number can be costly if a computation creates huge integers.

Next: Type Predicates for Numbers, Previous: Integer Basics, Up: Numbers [Contents][Index]

3.2 Floating-Point Basics ¶

Floating-point numbers are useful for representing numbers that are not integral. The range of floating-point numbers is the same as the range of the C data type double on the machine you are using. On almost all computers supported by Emacs, this is IEEE binary64 floating point format, which is standardized by IEEE Std 754-2019 and is discussed further in David Goldberg’s paper “What Every Computer Scientist Should Know About Floating-Point Arithmetic”. On modern platforms, floating-point operations follow the IEEE-754 standard closely; however, results are not always rounded correctly on some systems, notably 32-bit x86.

On some old computer systems, Emacs may not use IEEE floating-point. We know of one such system on which Emacs runs correctly, but does not follow IEEE-754: the VAX running NetBSD using GCC 10.4.0, where the VAX ‘D_Floating’ format is used instead. IBM System/370-derived mainframes and their XL/C compiler are also capable of utilizing a hexadecimal floating point format, but Emacs has not yet been built in such a configuration.

The read syntax for floating-point numbers requires either a decimal point, an exponent, or both. Optional signs (‘+’ or ‘-’) precede the number and its exponent. For example, ‘1500.0’, ‘+15e2’, ‘15.0e+2’, ‘+1500000e-3’, and ‘.15e4’ are five ways of writing a floating-point number whose value is 1500. They are all equivalent. Like Common Lisp, Emacs Lisp requires at least one digit after a decimal point in a floating-point number that does not have an exponent; ‘1500.’ is an integer, not a floating-point number.

Emacs Lisp treats -0.0 as numerically equal to ordinary zero with respect to numeric comparisons like =. This follows the IEEE floating-point standard, which says -0.0 and 0.0 are numerically equal even though other operations can distinguish them.

The IEEE floating-point standard supports positive infinity and negative infinity as floating-point values. It also provides for a class of values called NaN, or “not a number”; numerical functions return such values in cases where there is no correct answer. For example, (/ 0.0 0.0) returns a NaN. A NaN is never numerically equal to any value, not even to itself. NaNs carry a sign and a significand, and non-numeric functions treat two NaNs as equal when their signs and significands agree. Significands of NaNs are machine-dependent, as are the digits in their string representation.

When NaNs and signed zeros are involved, non-numeric functions like eql, equal, sxhash-eql, sxhash-equal and gethash determine whether values are indistinguishable, not whether they are numerically equal. For example, when x and y are the same NaN, (equal x y) returns t whereas (= x y) uses numeric comparison and returns nil; conversely, (equal 0.0 -0.0) returns nil whereas (= 0.0 -0.0) returns t.

Here are read syntaxes for these special floating-point values:

infinity: ‘1.0e+INF’ and ‘-1.0e+INF’
not-a-number: ‘0.0e+NaN’ and ‘-0.0e+NaN’

Infinities and NaNs are not available on legacy systems that lack IEEE floating-point arithmetic. On a circa 1980 VAX, for example, Lisp reads ‘1.0e+INF’ as a large but finite floating-point number, and ‘0.0e+NaN’ as some other non-numeric Lisp object that provokes an error if used numerically.

The following functions are specialized for handling floating-point numbers:

Function: isnan x ¶: This predicate returns t if its floating-point argument is a NaN, nil otherwise.

"index-fre